Select Active File

Many of the pipeline commands in Visual3D act on the active files only. Using this command the user can determine what files are active and therefore will be processed.

Pipeline Command

The pipeline command below is used to select the Active_Files

Select_Active_File
! /FILE_NAME=
! /QUERY=
! /SUBJECT_TAGS=NO_SUBJECT
;

File_Name

The parameter /File_Name= can be a single file, a TAG referring to all files with that TAG, or the keyword ALL_FILES, which makes all of the files in the Visual3D Workspace active.

Note: Visual3D defines files by their full pathname. For example, the following command will not be recognized

Select_Active_File
/FILE_NAME= file1.c3d
;

To fix the example above, you define the full pathname:

Select_Active_File
/FILE_NAME= c:\data\session1\file1.c3d
;

or you can use a wildcard:

Select_Active_File
/FILE_NAME= *file1.c3d
;

or you can specify a TAG:

Select_Active_File
/FILE_NAME= TAG1
;

Query

The Query option (Visual3D Professional Only) allows you to select a subset of the files referred by to FILE_NAME. You can query using expressions:

/QUERY=METRIC::PROCESSED::MASS > 75

Example 1: Global_Workspace

This example shows how to make the Global Workspace active

Select_Active_File
/FILE_NAME=GLOBAL
! /QUERY=
;

Example 2 - ALL_FILES and OR Query

From ALL_FILES select files that are tagged TAG1 or TAG2. Note there are multiple syntaxes for the "or". Two are shown below:

Using the "+" as the "OR" operator

Select_Active_File
/FILE_NAME=ALL_FILES
/QUERY=TAG1 + TAG2
;

Using "|" as the "OR" operator

Select_Active_File
/FILE_NAME=ALL_FILES
/QUERY=TAG1 | TAG2
;

Example 3 - ALL_FILES AND and NOT Query

From ALL_FILES select files that are TAG1 AND NOT TAG2 using the operators "&" and "NOT"

Select_Active_File
/FILE_NAME=ALL_FILES
/QUERY=TAG1 & NOT(TAG2)
;

Example 4 - ALL_FILES and a wildcard

From ALL_FILES select files that do not contain the wildcard *run*.c3d

This cannot be done in one step. Command will be used to tag the files prior to using the Select_Active command.

! Assign tag RUN to files with "run" in the pathname
Assign_Tags_To_Files
/MOTION_FILE_NAMES=*run*.c3d
! /QUERY=
/TAGS=RUN
;

! Assign tag NOT_RUN to files that are not tagged RUN
Assign_Tags_To_Files
/MOTION_FILE_NAMES=ALL_FILES
/QUERY=NOT(RUN)
/TAGS=NOT_RUN
;
 
! Select NOT_RUN as the active files
Select_Active_File
/FILE_NAME=NOT_RUN
! /QUERY=
;

Back to Pipeline Commands Reference